// planetoids
//       - a planetoid simulator
//
//  based on some SWF code I found, not attributed to anyone
//
//  Scott "Jerry" Lawrence
//

float[] x = new float[100]; // x positions of planetoids
float[] y = new float[100]; // y positions of planetoids
float[] z = new float[100]; // z positions of planetoids
color[] c = new color[100]; // colors of planetoids

int nplanetoids=90;  // number of planetoids

void setup()
{
  size( 300, 300 );
  background( 0,0,0 );
  colorMode( HSB, 100 );

  // create the initial universe
  for( int j=0 ; j<nplanetoids ; j++ )
  {
    newPlanetoid( j );
  }
}

void loop()
{
  // draw each planetoid
  for( int j=0 ; j<nplanetoids ; j++ )
  {
    // do the z-depth computations
    float tx = (width/2) + ( x[j] / z[j] );
    float ty = (height/2) + ( y[j] / z[j] );

    float s = 7 - z[j];
    float b = (s*20) - 40;

    // set the brightness of the planetoid
    fill( red(c[j])/100 * b,
          green(c[j])/100 * b,
          blue(c[j])/100 * b
    );
    
    /* stars */
    //triangle( tx, ty-s-s,  tx+s, ty+s,  tx-s, ty+s );
    //triangle( tx, ty+s+s,  tx+s, ty-s,  tx-s, ty-s );
    
    /* circles */
    ellipse( tx, ty, s/z[j], s/z[j] );

    // adjust Z
    z[j] -= 0.01 + 0.08 * (mouseX+mouseY)/(width+height);

    // create new planetoid if needed
    if ( (tx<-20) || (tx>width) || (ty<-20) || (ty>height) )
      newPlanetoid( j );
  }
}

// newPlanetoid -- generate a new planetoid
void newPlanetoid( int idx )
{
  x[idx] = -500 + random(1000);
  y[idx] = -500 + random(1000);
  z[idx] = random(2);
  noStroke();

  // Hue   - 1..100 / 100
  // Shade - 40..60 / 100
  // Value - 75..100 / 100
  c[idx] = ( color( random( 100 ), 40 + random( 20 ),  75+random(25) ));

}