// Scale Blox demo
//
//  Scott "Jerry" Lawrence
//  http://www.cis.rit.edu/~jerry/Software/p5
//  2003-09-07
//

// I made this as a drop-in helper for a rewrite my QuadBlok, as well as for 
// a new version of my sand simulator using a Cellular Automata.  I figured 
// that others might find this useful, so I'm releasing it on its own. :)

ScaleBlox sb;
int xs = 18; // xsize of the array
int ys = 15; // ysize of the array
int ps = 10; // pixel size for the Ÿberpixels
int fm = 2;  // frame size -- 0 for no frame

// for our mouse position indicator
color white;

// set this to 'true' to digitize video
boolean useVideo = false;

// non-video related things
int rrrr = 0;

// video related things
boolean newFrame = false;

void setup()
{
  size( 200, 200 );
  background( 0, 0, 0 );
  white = color( 255, 255, 255 );
  
  sb = new ScaleBlox( xs, ys, // size of the Ÿberpixels
                      100-(xs*ps/2) + fm/2, 100-(ys*ps/2)+fm/2, // center the SB
                      ps, // Ÿberpixel size
                      fm ); // 2 pixel frame
  if( useVideo )
    beginVideo( xs, ys, 15 );
}

void videoEvent()
{
  newFrame = true;
}

  
void loop()
{
  if( newFrame && useVideo ) 
  {
    // copy over the video frame...
    int pos = 0;
    for( int y=0; y<ys ; y++ )
      for( int x=0; x<xs ; x++ )
      {
        sb.setC( x, y, video.pixels[pos] );
        pos++;
      }

    newFrame = false;
  } else {
    // draw something interesting instead
    for( int i = 0 ; i < xs ; i++ )
      for( int j = 0 ; j < ys ; j++ )
      {
        sb.setC( i, j, color( (rrrr*10)%255, i*2, (int)random( 255 ) ) );
      }
    rrrr++;
  }
  
  // turn the pixel under the mouse white (show off decode() and decodeY() )
  sb.setC( sb.decodeX( mouseX ), sb.decodeY( mouseY ), white );
  
  // draw boxes if the mousebutton is pressed
  if( mousePressed )
    stroke( 255 );
  else
    noStroke();
  sb.draw();
  
  // a little something to save a screengrab...
  if( keyPressed )
  {
    if( key == 'G' )
      screenGrab();
  }
}



// Scale Blox class -- draw Ÿberpixels!
class ScaleBlox
{
  color data[][]; // the color data itself
  int x;  int y;  // the position for the upper right corner
  int w;  int h;  // the size of the matrix
  int sz;         // the size of each node
  int frame;      // the size of the frame
  
  // for comparisons
  color black;
  
  ScaleBlox(  int width, int height, 
              int xpos, int ypos, 
              int ssize, int fframe )
  {
    data = new color[width][height];
    x = xpos;
    y = ypos;
    w = width;
    h = height;
    sz = ssize;
    frame = fframe;
    black = color( 0, 0, 0 );
  }
  
  // decodeX -- figure out where in the drawn array the passed in window position is
  int decodeX( int xx )
  {
    int maxX = x+(w*sz);
    int minX = x;
    
    if( xx <= minX ) return 0;
    if( xx >= maxX ) return w-1;
    return( (xx-x) / sz );
  }
  
  // decodeY -- figure out where in the drawn array the passed in window position is
  int decodeY( int yy )
  {
    int maxY = y+(h*sz);
    int minY = y;
    
    if( yy <= minY ) return 0;
    if( yy >= maxY ) return h-1;
    return( (yy-y) / sz );
  }
  
  
  // set a color in the array
  void setC( int xx, int yy, color cc )
  {
    data[xx][yy] = cc;
  }
  
  // return the color at xx,yy
  color getC( int xx, int yy )
  {
    return( data[xx][yy] );
  }
  
  // return true if the element is not black
  boolean occupied( int xx, int yy )
  {
    return( data[xx][yy] != black );
  }
  
  // clear the frame
  void clear()
  {
    for( int i=0 ; i<w ; i++ )
      for( int j=0 ; j<h ; j++ )
      {
        data[i][j] = black;
      }
  }
  
  // draw the pixels to the screen  
  void draw()
  {
    // first offset everything
    push();
    translate( x, y );
    
    // set up some loop variables to speed up things
    int szmf = sz-frame;
    int isz = 0;
    int jsz = 0;

    // draw the Ÿberpixels
    for( int i=0 ; i<w ; i++ )
    {
      isz = i*sz;
      jsz = 0;
      for( int j=0 ; j<h ; j++ )
      {
        fill( data[i][j] );
        rect( isz, jsz, szmf, szmf );
        jsz += sz;
      }
      isz += sz;
    }

    pop();    
  }
  
  
}